alias F5 exportline
alias /exportline {
  ;-- Iterator vars
  var %i = 1
  var %j = $cb(0)
  ;-- RegExp's
  var %re.eline /\*\* Export Line \[ver ([\d]+)\] -- (.*) \[ver ([\d]+)\]: \*\*/
  var %re.pname /(The Province of|Buildings Report of|Science Intelligence on|Military Intelligence on) (.*) \(([\d]+):([\d]+)\)/
  var %re.netdef /Net Defense at Home \(from Utopia\): (.*)/
  var %re.back /\*\* Armies [#\/\d]+ \(Back in (.*) hours\) \*\*/
  ;-- Scan the Clipboard
  while (%i <= %j) {
    ;-- Get Province name
    if ($regex($cb(%i),%re.pname)) {
      var %el.pname $regml(2) ( $+ $regml(3) $+ : $+ $regml(4) $+ )
    }
    if ($regex($cb(%i),%re.netdef)) {
      var %el.netdef $regml(1) 
    }
    if ($regex($cb(%i),%re.back)) {
      say !xarmy $replace($regml(1),$chr(58),$chr(46)) %el.pname
    }
    ;-- Get Exportline and Type
    if ($regex($cb(%i),%re.eline)) {
      var %el.type = $regml(2) v. $+ $regml(1) $+ . $+ $regml(3)
      var %k $calc(%i +1)
      while ((%k <= %j) && ($cb(%k) != $null)) {
        var %el.eline %el.eline $cb(%k)
        inc %k
      }
    }
    inc %i
  }
  if (%el.eline != $null) {
    ;-- Vars
    ; %el.pname = province name
    ; %el.eline = exportline
    ; %el.type = exportline type and version
    ; %el.netdef = netdef home (som only)
    say $+(IRC Export Line » %el.eline « %el.pname %el.type)
    if (%el.netdef != $null) say NetDef(home): %el.netdef
  }
  else {
    echo -tmg 4 !
  }
}
;-- Makes the Exportline clickable
on ^*:hotlink:*:*:{
  if ($regex($hotline,/IRC Export Line » (.*) «/)) {
    ; exportline is in $regml(1)
    if ($mouse.key & 1) clipboard $regml(1)
    return
  }
  else {
    halt
  }
}