;================================================
;=== QOQuote
;================================================

;Returns the quote file. You may change the quotes 
;####NOTE####: This is what you change to change where your quotes are stored!!!
;file for the entire script by changing this.
alias -l QuoteFile {
  return quotes.txt
}

;returns the quote formated to send. 
;####NOTE####: This is what you change to change the appearence of your quotes!!!
;To change this the variable $1 holds the quote number and $2-
;holds the quote itself.
alias -l GetQuoteStringFormat {
  return [QOQuote] :: !quote :: $1 :: $2- ::
}

;#####################################################################
;#####################################################################
;######## Change nothing past here. Unless your really smert! ########
;#####################################################################
;#####################################################################


;returns a quote string based on given input
;not for direct user use.
alias -l GetQuoteString {
  var %num
  var %text
  if ( $calc( $1 ) > 0 ) {
    %num = $calc( $1 )
    if ( %num < 1 || %num > $lines($QuoteFile) ) {
      %text = Quote %num not found.
      %num = -
    }
    else {
      %text = $read($QuoteFile, %num)
    }
  }
  else {
    if ( $1 != $null ) {
      %text = $read($QuoteFile, w, * $+ $1- $+ *)
      if ( $readn == 0 ) {
        %text = Quote ' $+ $1- $+ ' not found.
        %num = -
      }
      else {
        while ( $readn > 0 ) {
          %num = %num $+ , $+ $readn
          %temp = $read($QuoteFile, w, * $+ $1- $+ *, $calc($calc($readn)+1))
        }
        %num = $right(%num, $calc($len(%num)-1))
        if ( $count(%num,$chr(44)) > 0 ) {
          %text = String ' $+ $1- $+ ' found in quotes %num $+ .
          %num = -
        }
      }
    }
    else { 
      %num = $rand(1, $lines($QuoteFile))
      %text = $read($QuoteFile, %num)
    }
  }
  return $GetQuoteStringFormat(%num, %text)
}

;Add a quote to the quotes file
alias AddQuote { 
  write $QuoteFile $1- 
  echo [QOQuote] :: Added as $lines($QuoteFile) :: $1- :: 
}

;delete specifed quote #
alias DeleteQuote {
  if ( $calc( $1 ) > 0 ) {
    if ( $calc( $1 ) < 1 || $calc( $1 ) > $lines($QuoteFile) ) {
      echo [QOQuote] :: 4Error :: Quote $calc( $1 ) not found. :: 
    }
    else {
      echo [QOQuote] :: Deleted $calc( $1 ) :: $read($QuoteFile, $calc( $1 )) :: 
      write -dl $calc( $1 ) $QuoteFile
    }
  }
  else {
    echo [QOQuote] :: 4Error :: No quote to delete specified. :: 
  }
}

;say a quote in the current window (chan or query)
alias Quote {
  if ( $chan != $null ) {
    msg $chan $GetQuoteString($1-)
  }
  else {
    msg $active $GetQuoteString($1-)
  }
}

;Say !quote in the current chan and then give a quote
alias AllQuote {
  msg $chan !quote $1-
  quote $1-
}

;echo a quote to the user
alias EchoQuote {
  echo $GetQuoteString($1-)
}

;Trigger to give a quote in a channel or query
on 1:TEXT:!quote*:*:{
  if ( $chan != $null ) {
    msg $chan $GetQuoteString($2-)
  }
  else {
    msg $nick $GetQuoteString($2-)
  }
}

;echo how many quotes the user has
alias QuoteCount {
  echo You have $lines($QuoteFile) quotes in $QuoteFile
}

;#####################################################################
;#################### Dialog stuff and the like. #####################
;#####################################################################

;dialog table
dialog -l QOQDT {
  title "QOQuote"
  size -1 -1 600 268
  option pixel

  button "Close", 1, 492 8 100 25, ok
  button "Remove", 2, 492 138 100 25, disable
  button "Save Changes", 3, 492 171 100 25, disable

  list 4, 8 8 478 200
  edit "", 5, 8 208 584 50, disable, multi, vsbar
}

;init the form: load quotes into list
on 1:dialog:QOQDialog:init:0: {
  var %i
  var %line
  var %lines

  %lines = $lines($QuoteFile)
  %i = 1
  while ( %i <= %lines ) {
    did -a QOQDialog 4 $read($QuoteFile, %i)
    inc %i
  }
}

;handles removing the selected quote
on 1:dialog:QOQDialog:sclick:2: {
  var %line

  %line = $did(QOQDialog, 4, 1).sel

  did -d QOQDialog 4 %line
  did -b QOQDialog 2,5
  did -r QOQDialog 5
  write -dl $+ %line $QuoteFile 

  if ( %line > 1 ) {
    did -c QOQDialog 4 $calc(%line - 1)
    did -e QOQDialog 2
  }
}

;handles saving the changes one a quote
on 1:dialog:QOQDialog:sclick:3: {
  var %text
  var %i

  %i = 1
  while ( %i <= $did(QOQDialog, 5).lines ) {
    %text = %text $did(QOQDialog, 5, %i).text
    inc %i
  }

  did -b QOQDialog 3
  did -o QOQDialog 4 %qoquote.selline %text
  did -c QOQDialog 4 %qoquote.selline
  write -l $+ %qoquote.selline $QuoteFile %text
}

;handles a quote being selected in the list
on 1:dialog:QOQDialog:sclick:4: {
  %qoquote.selline = $did(QOQDialog, 4, 1).sel
  did -e QOQDialog 2,5
  did -b QOQDialog 3
  did -r QOQDialog 5
  did -a QOQDialog 5 $did(QOQDialog, 4, $did(QOQDialog, 4, 1).sel).text
}

;handles enabling the save button when a quote is changed
on 1:dialog:QOQDialog:edit:5: {
  did -e QOQDialog 3
}

;command to show the dialog...wewt
alias QuoteEdit {
  /dialog -m QOQDialog QOQDT
}